Utilizando eventos do Excel - Parte 3

Fechando nossos exemplos sobre uso de eventos no Excel, vamos ver exemplos utilizando os eventos do objeto Workbook.

Primeiramente o evento Workbook_Open, que ativado quando o arquivo é aberto.
No exemplo a seguir são realizadas uma série de alterações no modo em que o arquivo do Excel é exibido.


Private Sub Workbook_Open()


Dim Plan


'Faz que o código continue sendo executado caso ocorra um erro
On Error Resume Next


'Alteração dos parâmetros de exibição do Excel
With Application
    'Ativar exibição de tela inteira
    .DisplayFullScreen = True
    'Desativar a exibição da barra de fórmulas
    .DisplayFormulaBar = False
    'Desativar a exibição da barra de status
    .DisplayStatusBar = False
End With


'Alteração dos parâmetros de exibição da janela
With ActiveWindow
    'Desativar a exibição dos cabeçalhos
    .DisplayHeadings = False
    'Desativar a exibição da barra de rolagem horizontal
    .DisplayHorizontalScrollBar = False
    'Desativar a exibição da barra de rolagem vertical
    .DisplayVerticalScrollBar = False
    'Desativar a exibição das guias de planilha
    .DisplayWorkbookTabs = False
End With


For Each Plan In ThisWorkbook.Worksheets
    'Manter exibida apenas a planilha "Principal
    If Plan.Name <> "Principal" Then Plan.Visible = False
Next


End Sub

É interessante desfazer as alterações que afetam o Excel (Application) quando o arquivo é fechado. Para isso podemos lançar mão do evento Workbook_BeforeClose.


Private Sub Workbook_BeforeClose(Cancel As Boolean)
'Faz que o código continue sendo executado caso ocorra um erro
On Error Resume Next


'Restauração dos parâmetros de exibição do Excel
With Application
    'Inibir exibição de tela inteira
    .DisplayFullScreen = False
    'Ativar a exibição da barra de fórmulas
    .DisplayFormulaBar = True
    'Ativar a exibição da barra de status
    .DisplayStatusBar = True
End With
End Sub

[ ]s